func09

/**
* お絵かきツールのメインクラス
* @author mitsuru.haga@gmail.com
* @version 0.1
*/

package paint {

    import paint.*;
    import flash.display.Sprite;
    import flash.events.*;

    public class Paint extends Sprite{

        //  ブラシ
        protected var brush:Brush;

        //  ブラシコレクション
        protected var brushCollection:Array = [];

        //  カンバス
        protected var canvas:Canvas;

        //  背景
        protected var background:Background;

        /**
        * コンストラクタ
        */
        public function Paint(){
            initialize();
        }

        /**
        * 初期化
        * @return
        */
        protected function initialize():void{

            //  ブラシを配列にどんどん追加
            brushCollection.push( new Brush( 'Red', 5, 0xFF0000 ) );
            brushCollection.push( new Brush( 'Blue', 5, 0x0000FF ) );
            brushCollection.push( new Brush( 'Green', 5, 0x00FF00 ) );

            //  ランダムにブラシを決定する
            brush = brushCollection[ uint( Math.random()*brushCollection.length ) ];

            //  背景を作る
            background = new Background();
            background.buttonMode = true;
            background.width = stage.stageWidth;
            background.height = stage.stageHeight;
            background.addEventListener( MouseEvent.MOUSE_DOWN, onCanvasMouseDownHandler );
            background.addEventListener( MouseEvent.MOUSE_UP, onCanvasMouseUpHandler );
            addChild( background );

            //  カンバスを作る
            canvas = new Canvas();
            canvas.addEventListener( MouseEvent.MOUSE_DOWN, onCanvasMouseDownHandler );
            canvas.addEventListener( MouseEvent.MOUSE_UP, onCanvasMouseUpHandler );
            addChild( canvas );

        }

        /**
        * マウスを押した場合
        * 線を描く準備
        * @param    e
        * @return
        */
        protected function onCanvasMouseDownHandler( e:MouseEvent ):void {
            trace( 'draw start' );
            brush = brushCollection[ uint( Math.random()*brushCollection.length ) ];
            canvas.graphics.lineStyle( brush.thickness, brush.color, 1 );
            canvas.graphics.moveTo( mouseX, mouseY );
            canvas.addEventListener( Event.ENTER_FRAME, drawingHandler );
        }

        /**
        * マウスを放した場合
        * 線を描くの終わり
        * @param    e
        * @return
        */
        protected function onCanvasMouseUpHandler( e:MouseEvent ):void {
            trace('draw finish');
            canvas.graphics.endFill();
            canvas.removeEventListener( Event.ENTER_FRAME, drawingHandler );
        }

        /**
        * マウスを押している間
        * 線を描き続ける
        * @param    e
        * @return
        */
        protected function drawingHandler( e:Event ):void{
            trace('drawing');
            canvas.graphics.lineTo( mouseX, mouseY );
        }
    }

}